unirationalityOfD1 -- compute a random normal curve of degree 14 and genus 8 in P^6 with an extra syzygy of rank 6

i1 : kk=ZZ/10007;R=kk[x_0..x_6];

i3 : setRandomSeed("goodExample");

i4 : I=unirationalityOfD1 R;

o4 : Ideal of R

i5 : betti res I

            0 1  2  3  4 5
o5 = total: 1 8 36 56 35 8
         0: 1 .  .  .  . .
         1: . 7  1  .  . .
         2: . 1 35 56 35 8

o5 : BettiTally

i6 : R1=kk[x_0..x_6,MonomialOrder=>Eliminate 3];

i7 : R2=kk[x_3..x_6] -- coordinate ring of P^3

o7 = R2

o7 : PolynomialRing

i8 : I1=selectInSubring(1, gens gb sub(I,R1));

              1        14
o8 : Matrix R1  <--- R1

i9 : I2=ideal mingens ideal sub(I1,R2); -- the curve projected into P^3

o9 : Ideal of R2

i10 : betti(fI2= res I2)

             0 1  2 3
o10 = total: 1 8 14 7
          0: 1 .  . .
          1: . .  . .
          2: . .  . .
          3: . .  . .
          4: . .  . .
          5: . 7  . .
          6: . 1 14 7

o10 : BettiTally

i11 : degree I2==14, genus I2 ==8

o11 = (true, true)

o11 : Sequence

i12 : singI2=I2+minors(2,jacobian I2);

o12 : Ideal of R2

i13 : dim singI2 == 0 -- => I defines a smooth curve

o13 = true

i14 : kk=ZZ/10007;R=kk[x_0..x_6];

i16 : setRandomSeed("goodExample");

i17 : C=unirationalityOfD1 R;

o17 : Ideal of R

i18 : betti (fC = res C)

             0 1  2  3  4 5
o18 = total: 1 8 36 56 35 8
          0: 1 .  .  .  . .
          1: . 7  1  .  . .
          2: . 1 35 56 35 8

o18 : BettiTally

i19 : s=(fC.dd_2)_{0};

              8       1
o19 : Matrix R  <--- R

i20 : J=ideal(fC.dd_1*syz transpose syz jacobian transpose s);

o20 : Ideal of R

i21 : betti res J

             0 1  2  3  4 5 6
o21 = total: 1 6 16 27 22 7 1
          0: 1 .  .  .  . . .
          1: . 6  1  .  . . .
          2: . . 15  6  1 . .
          3: . .  . 21 21 6 1
          4: . .  .  .  . 1 .

o21 : BettiTally

i22 : pt = ideal s; -- the ideal of the point

o22 : Ideal of R

i23 : dim pt == 1

o23 = true

i24 : CE =J:pt;

o24 : Ideal of R

i25 : betti res CE

             0 1  2  3 4 5
o25 = total: 1 7 22 22 7 1
          0: 1 .  .  . . .
          1: . 6  1  . . .
          2: . 1 21 21 1 .
          3: . .  .  1 6 .
          4: . .  .  . . 1

o25 : BettiTally

i26 : E=CE:C; -- the ideal of the elliptic normal curve

o26 : Ideal of R

i27 : betti res E

             0  1  2  3  4 5
o27 = total: 1 14 35 35 14 1
          0: 1  .  .  .  . .
          1: . 14 35 35 14 .
          2: .  .  .  .  . 1

o27 : BettiTally

i28 : dim E == 2, degree E == 7, genus E ==1

o28 = (true, true, true)

o28 : Sequence

i29 : degree (E+C)==14, dim (E+pt)==0, dim (C+pt)==0

o29 = (true, true, true)

o29 : Sequence

i30 : Er=sub(E,random(R^1,R^{7:-1}));

o30 : Ideal of R

i31 : R1=kk[x_4..x_6,x_0..x_3,MonomialOrder=>Eliminate 3];

i32 : R2=kk[x_0..x_3] -- coordinate ring of P^3

o32 = R2

o32 : PolynomialRing

i33 : E1=selectInSubring(1, gens gb sub(Er,R1));

               1        8
o33 : Matrix R1  <--- R1

i34 : E2=ideal mingens ideal sub(E1,R2); -- the curve projected into P^3

o34 : Ideal of R2

i35 : betti(fE2= res E2)

             0 1 2 3
o35 = total: 1 7 7 1
          0: 1 . . .
          1: . . . .
          2: . . . .
          3: . 7 7 .
          4: . . . 1

o35 : BettiTally

i36 : degree E2==7, genus E2 ==1

o36 = (true, true)

o36 : Sequence

i37 : singE2=E2+minors(2,jacobian E2);

o37 : Ideal of R2

i38 : dim singE2 == 0 -- => E is a smooth curve elliptic curve

o38 = true