getCurveOnKoszulDivisor -- get a curve of genus 8 and degree 14 in P^6 on the Koszul divisor with syzygy of rank rk

i1 : kk=ZZ/19;R=kk[x_0..x_6]

o2 = R

o2 : PolynomialRing

i3 : setRandomSeed("getDesiredFCurveFast");

i4 : time I=getCurveOnKoszulDivisor(7,R);
     -- used 5.89941 seconds

o4 : Ideal of R

i5 : betti (fI= res I)

            0 1  2  3  4 5
o5 = total: 1 8 36 56 35 8
         0: 1 .  .  .  . .
         1: . 7  1  .  . .
         2: . 1 35 56 35 8

o5 : BettiTally

i6 : R1=kk[x_0..x_6,MonomialOrder=>Eliminate 3];

i7 : R2=kk[x_3..x_6] -- coordinate ring of P^3

o7 = R2

o7 : PolynomialRing

i8 : I1=selectInSubring(1, gens gb sub(I,R1));

              1        14
o8 : Matrix R1  <--- R1

i9 : I2=ideal mingens ideal sub(I1,R2); -- the curve projected into P^3

o9 : Ideal of R2

i10 : betti(fI2= res I2)

             0 1  2 3
o10 = total: 1 8 14 7
          0: 1 .  . .
          1: . .  . .
          2: . .  . .
          3: . .  . .
          4: . .  . .
          5: . 7  . .
          6: . 1 14 7

o10 : BettiTally

i11 : degree I2==14, genus I2 ==8

o11 = (true, true)

o11 : Sequence

i12 : singI2=I2+minors(2,jacobian I2);

o12 : Ideal of R2

i13 : dim singI2 == 0 -- => I defines a smooth curve

o13 = true

i14 : s=ideal mingens ideal (fI.dd_2)_{0}

o14 = ideal (x , x , x , x , x , x , x )
              6   5   4   3   2   1   0

o14 : Ideal of R

i15 : dim s == 0 -- => the extra syzygy has full rank 7

o15 = true